PropertyChanges Class Reference

The PropertyChanges element describes new property bindings or values for a state. More...

Detailed Description

The PropertyChanges element describes new property bindings or values for a state.

Since

4.7

PropertyChanges is used to define the property values or bindings in a State . This enables an item's property values to be changed when it QML States.

To create a PropertyChanges object, specify the target item whose properties are to be modified, and define the new property values or bindings. For example:

import QtQuick 1.0

Item {
    id: container
    width: 300; height: 300

    Rectangle {
        id: rect
        width: 100; height: 100
        color: "red"

        MouseArea { 
           id: mouseArea
           anchors.fill: parent 
        }

        states: State {
           name: "resized"; when: mouseArea.pressed
           PropertyChanges { target: rect; color: "blue"; height: container.height }
        }
    }
}

When the mouse is pressed, the Rectangle changes to the resized state. In this state, the PropertyChanges object sets the rectangle's color to blue and the height value to that of container.height.

Note this automatically binds rect.height to container.height in the resized state. If a property binding should not be established, and the height should just be set to the value of container.height at the time of the state change, set the explicit property to true.

A PropertyChanges object can also override the default signal handler for an object to implement a signal handler specific to the new state:

PropertyChanges {
    target: myMouseArea
    onClicked: doSomethingDifferent()
}

Note

PropertyChanges can be used to change anchor margins, but not other anchor values; use AnchorChanges for this instead. Similarly, to change an Item's Item::parent value, use ParentChanges instead.

Resetting property values

The undefined value can be used to reset the property value for a state. In the following example, when theText changes to the widerText state, its width property is reset, giving the text its natural width and displaying the whole string on a single line.

Rectangle {
    width: 300; height: 200

    Text {
        id: myText
        width: 50
        wrapMode: Text.WordWrap
        text: "a text string that is longer than 50 pixels"

        states: State {
            name: "widerText"
            PropertyChanges { target: myText; width: undefined }
        }
    }

    MouseArea {
        anchors.fill: parent
        onClicked: myText.state = "widerText"
    }
}

Immediate property changes in transitions

When QML Animation and Transitions{Transitions} are used to animate state changes, they animate properties from their values in the current state to those defined in the new state (as defined by PropertyChanges objects). However, it is sometimes desirable to set a property value immediately during a Transition , without animation; in these cases, the PropertyAction element can be used to force an immediate property change.

See the PropertyAction documentation for more details.

See also

{declarative/animation/states}{states example}, {qmlstate}{States}, QtDeclarative

---

The documentation for this class was generated from the following file:

• /src/declarative/util/qdeclarativepropertychanges.cpp